home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / compuserve-file-archive / 12 C64 Telecom / T18MAN.SDA / SET.TOD.FROM.RTC (.txt) < prev    next >
Encoding:
Commodore BASIC  |  2019-04-13  |  1.8 KB  |  66 lines
  1. 100 PRINTCHR$(14)CHR$(147)
  2. 110 REM -------------------------------
  3. 120 PRINT"[210]EAD TIME FROM THE [210]EAL [212]IME [195]LOCK,"
  4. 130 PRINT"AND SET THE 64'S [212]IME-[207]F-[196]AY CLOCK."
  5. 140 PRINT:PRINT"[212]HEN, LOAD AND RUN [212][197][210][205][201][206][193][204] 1"
  6. 150 PRINT
  7. 151 REM -------------------------------
  8. 155 REM GET DEVICE NUMBER LAST USED
  9. 159 REM -------------------------------
  10. 160 DV=PEEK(186):IF DV<8 THEN DV=8
  11. 170 PRINT"[211]ET DEVICE NUMBER OF [198][196]?000 DRIVE"
  12. 180 PRINT"OR [210][193][205][204]INK WHICH HAS THE [210][212][195]."
  13. 190 PRINT:PRINT"[196]EVICE # =";DV;"[157][157][157][157]";
  14. 200 IF DV>9 THEN PRINT"[157]";
  15. 210 INPUT DV:PRINT
  16. 220 REM -------------------------------
  17. 230 REM GET AND SHOW THE DATE AND TIME
  18. 240 REM -------------------------------
  19. 250 OPEN15,DV,15,"T-RA"
  20. 260 GET#15,B$,C$:PRINTB$;C$;
  21. 270 FOR I=0 TO 20
  22. 280 GET#15,A$:PRINTA$;
  23. 290 IF ST<>64THEN NEXT
  24. 300 CLOSE15:PRINT
  25. 310 IF B$+C$="31" THEN PRINT"[196]EVICE";DV;"DOES NOT HAVE AN [210][212][195].":PRINT:GOTO170
  26. 320 REM -------------------------------
  27. 330 REM GET TIME IN BCD FORMAT
  28. 340 REM -------------------------------
  29. 350 OPEN15,DV,15,"T-RB"
  30. 360 FOR I=0 TO 8
  31. 370 GET#15,A$:A(I)=ASC(A$+CHR$(0))
  32. 380 IF ST<>64THEN NEXT
  33. 390 CLOSE15:PRINT
  34. 399 REM --------------------------
  35. 400 REM SET THE TIME-OF-DAY
  36. 410 REM REGISTERS AT $DC08-DC0B
  37. 420 REM IN THE 64
  38. 430 REM --------------------------
  39. 431 REM ADD AM/PM FLAG TO HOURS VALUE
  40. 440 IF A(7)<>0THEN A(4)=A(4) OR 128
  41. 441 REM --------------------------
  42. 442 REM INDICATE INTENT TO SET TOD CLOCK
  43. 450 POKE56335,PEEK(56335)AND127
  44. 451 REM --------------------------
  45. 452 REM SET REGISTER VALUES
  46. 460 POKE(56331),A(4):REM HOURS
  47. 470 POKE(56330),A(5):REM MINUTES
  48. 480 POKE(56329),A(6):REM SECONDS
  49. 490 POKE(56328),0:REM TENTHS OF SECS
  50. 500 REM --------------------------
  51. 510 REM TOD CLOCK SET
  52. 511 REM NOW GET TERMINAL 1
  53. 520 REM --------------------------
  54. 550 T$="TERMINAL1.822P":REM DEFAULT
  55. 560 PRINT:PRINT"[211]ET NAME OF PROGRAM TO BE RUN:"
  56. 570 PRINT"  "T$:PRINT"[145]";:INPUT T$
  57. 571 REM -------------------------------
  58. 572 REM SET DEVICE TO LOAD PROGRAM FROM
  59. 573 REM -------------------------------
  60. 574 PRINT"[211]ET DEVICE NUMBER TO LOAD FROM"
  61. 575 PRINT:PRINT"[196]EVICE # =";DV;"[157][157][157][157]";
  62. 576 IF DV>9 THEN PRINT"[157]";
  63. 577 INPUT DV:PRINT
  64. 580 PRINT:PRINT"[204]OADING....."
  65. 590 LOAD T$,DV
  66.